第3章 Terraform を使用した ROSA (クラシックアーキテクチャー) クラスターの作成

手順

1. オプション: この手順の実行中、現在のディレクトリーに Terraform ファイルが作成されます。次のコマンドを実行すると、これらのファイルを保存する新しいディレクトリーを作成してそこに移動できます。

   $ mkdir terraform-cluster && cd terraform-cluster

2. オフラインの Red Hat OpenShift Cluster Manager トークン を使用して、アカウントに権限を付与します。

3. オフライントークンをコピーし、次のコマンドを実行してトークンを環境変数として設定します。

   $ export RHCS_TOKEN=<your_offline_token>

   注記

   この環境変数は、マシンの再起動やターミナルの終了など、各セッションの終了時にリセットされます。

手順

1. 次のコマンドを実行して、main.tf ファイルを作成します。

   $ cat<<-EOF>main.tf
   #
   # Copyright (c) 2023 Red Hat, Inc.
   #
   # Licensed under the Apache License, Version 2.0 (the "License");
   # you may not use this file except in compliance with the License.
   # You may obtain a copy of the License at
   #
   #   http://www.apache.org/licenses/LICENSE-2.0
   #
   # Unless required by applicable law or agreed to in writing, software
   # distributed under the License is distributed on an "AS IS" BASIS,
   # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
   # See the License for the specific language governing permissions and
   # limitations under the License.
   #
   
   terraform {
     required_providers {
       aws = {
         source  = "hashicorp/aws"
         version = ">= 4.20.0"
       }
       rhcs = {
         version = ">= 1.6.2"
         source  = "terraform-redhat/rhcs"
       }
     }
   }
   
   # Export token using the RHCS_TOKEN environment variable
   provider "rhcs" {}
   
   provider "aws" {
     region = var.aws_region
     ignore_tags {
       key_prefixes = ["kubernetes.io/"]
     }
     default_tags {
       tags = var.default_aws_tags
     }
   }
   
   data "aws_availability_zones" "available" {}
   
   locals {
     # The default setting creates 3 availability zones. Set to "false" to create a single availability zones.
     region_azs = var.multi_az ? slice([for zone in data.aws_availability_zones.available.names : format("%s", zone)], 0, 3) : slice([for zone in data.aws_availability_zones.available.names : format("%s", zone)], 0, 1)
   }
   
   resource "random_string" "random_name" {
     length  = 6
     special = false
     upper   = false
   }
   
   locals {
     path                 = coalesce(var.path, "/")
     worker_node_replicas = try(var.worker_node_replicas, var.multi_az ? 3 : 2)
     # If cluster_name is not null, use that, otherwise generate a random cluster name
     cluster_name = coalesce(var.cluster_name, "rosa-\${random_string.random_name.result}")
   }
   
   # The network validator requires an additional 60 seconds to validate Terraform clusters.
   resource "time_sleep" "wait_60_seconds" {
     count = var.create_vpc ? 1 : 0
     depends_on = [module.vpc]
     create_duration = "60s"
   }
   
   module "rosa-classic" {
     source                 = "terraform-redhat/rosa-classic/rhcs"
     version                = "1.5.0"
     cluster_name           = local.cluster_name
     openshift_version      = var.openshift_version
     account_role_prefix    = local.cluster_name
     operator_role_prefix   = local.cluster_name
     replicas               = local.worker_node_replicas
     aws_availability_zones = local.region_azs
     create_oidc            = true
     private                = var.private_cluster
     aws_private_link       = var.private_cluster
     aws_subnet_ids         = var.create_vpc ? var.private_cluster ? module.vpc[0].private_subnets : concat(module.vpc[0].public_subnets, module.vpc[0].private_subnets) : var.aws_subnet_ids
     multi_az               = var.multi_az
     create_account_roles   = true
     create_operator_roles  = true
   # Optional: Configure a cluster administrator user <.>
   #
   # Option 1: Default cluster-admin user
   # Create an administrator user (cluster-admin) and automatically
   # generate a password by uncommenting the following parameter:
   #  create_admin_user = true
   # Generated administrator credentials are displayed in terminal output.
   #
   # Option 2: Specify administrator username and password
   # Create an administrator user and define your own password
   # by uncommenting and editing the values of the following parameters:
   #  admin_credentials_username = <username>
   #  admin_credentials_password = <password>
   
     depends_on = [time_sleep.wait_60_seconds]
   }
   EOF

   <.> オプション：適切なパラメーターをアンコメントし、その値を編集して、クラスターの作成中に管理者ユーザーを作成します。

2. 次のコマンドを実行して、variables.tf ファイルを作成します。

   注記

   クラスターを構築するコマンドを実行する 前 に、このファイルをコピーして編集します。

   $ cat<<-EOF>variables.tf
   #
   # Copyright (c) 2023 Red Hat, Inc.
   #
   # Licensed under the Apache License, Version 2.0 (the "License");
   # you may not use this file except in compliance with the License.
   # You may obtain a copy of the License at
   #
   #   http://www.apache.org/licenses/LICENSE-2.0
   #
   # Unless required by applicable law or agreed to in writing, software
   # distributed under the License is distributed on an "AS IS" BASIS,
   # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
   # See the License for the specific language governing permissions and
   # limitations under the License.
   #
   variable "openshift_version" {
     type        = string
     default     = "4.14.20"
     description = "Desired version of OpenShift for the cluster, for example '4.14.20'. If version is greater than the currently running version, an upgrade will be scheduled."
   }
   
   variable "create_vpc" {
     type        = bool
     description = "If you would like to create a new VPC, set this value to 'true'. If you do not want to create a new VPC, set this value to 'false'."
   }
   
   # ROSA Cluster info
   variable "cluster_name" {
     default     = null
     type        = string
     description = "The name of the ROSA cluster to create"
   }
   
   variable "additional_tags" {
     default = {
       Terraform   = "true"
       Environment = "dev"
     }
     description = "Additional AWS resource tags"
     type        = map(string)
   }
   
   variable "path" {
     description = "(Optional) The arn path for the account/operator roles as well as their policies."
     type        = string
     default     = null
   }
   
   variable "multi_az" {
     type        = bool
     description = "Multi AZ Cluster for High Availability"
     default     = true
   }
   
   variable "worker_node_replicas" {
     default     = 3
     description = "Number of worker nodes to provision. Single zone clusters need at least 2 nodes, multizone clusters need at least 3 nodes"
     type        = number
   }
   
   variable "aws_subnet_ids" {
     type        = list(any)
     description = "A list of either the public or public + private subnet IDs to use for the cluster blocks to use for the cluster"
     default     = ["subnet-01234567890abcdef", "subnet-01234567890abcdef", "subnet-01234567890abcdef"]
   }
   
   variable "private_cluster" {
     type        = bool
     description = "If you want to create a private cluster, set this value to 'true'. If you want a publicly available cluster, set this value to 'false'."
   }
   
   #VPC Info
   variable "vpc_name" {
     type        = string
     description = "VPC Name"
     default     = "tf-qs-vpc"
   }
   
   variable "vpc_cidr_block" {
     type        = string
     description = "value of the CIDR block to use for the VPC"
     default     = "10.0.0.0/16"
   }
   
   variable "private_subnet_cidrs" {
     type        = list(any)
     description = "The CIDR blocks to use for the private subnets"
     default     = ["10.0.1.0/24", "10.0.2.0/24", "10.0.3.0/24"]
   }
   
   variable "public_subnet_cidrs" {
     type        = list(any)
     description = "The CIDR blocks to use for the public subnets"
     default     = ["10.0.101.0/24", "10.0.102.0/24", "10.0.103.0/24"]
   }
   
   variable "single_nat_gateway" {
     type        = bool
     description = "Single NAT or per NAT for subnet"
     default     = false
   }
   
   #AWS Info
   variable "aws_region" {
     type    = string
     default = "us-east-2"
   }
   
   variable "default_aws_tags" {
     type        = map(string)
     description = "Default tags for AWS"
     default     = {}
   }
   EOF

3. 以下のコマンドを実行して vpc.tf ファイルを作成します。

   $ cat<<-EOF>vpc.tf
   #
   # Copyright (c) 2023 Red Hat, Inc.
   #
   # Licensed under the Apache License, Version 2.0 (the "License");
   # you may not use this file except in compliance with the License.
   # You may obtain a copy of the License at
   #
   #   http://www.apache.org/licenses/LICENSE-2.0
   #
   # Unless required by applicable law or agreed to in writing, software
   # distributed under the License is distributed on an "AS IS" BASIS,
   # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
   # See the License for the specific language governing permissions and
   # limitations under the License.
   #
   module "vpc" {
     source  = "terraform-aws-modules/vpc/aws"
     version = "5.1.2"
   
     count = var.create_vpc ? 1 : 0
     name  = var.vpc_name
     cidr  = var.vpc_cidr_block
   
     azs             = local.region_azs
     private_subnets = var.private_subnet_cidrs
     public_subnets  = var.public_subnet_cidrs
   
     enable_nat_gateway   = true
     single_nat_gateway   = var.single_nat_gateway
     enable_dns_hostnames = true
     enable_dns_support   = true
   
     tags = var.additional_tags
   }
   EOF

   これで Terraform を起動する準備ができました。

手順

1. Terraform ファイルに基づいてリソースを作成するように Terraform を設定し、次のコマンドを実行します。

   $ terraform init

2. オプション: 次のコマンドを実行して、コピーした Terraform が正しいことを確認します。

   $ terraform validate

   出力例

   Success! The configuration is valid.

3. 次のコマンドを実行して、Terraform を使用してクラスターを作成します。

   $ terraform apply

   Terraform インターフェイスでは、クラスターを作成するために次のような 2 つの質問が尋ねられます。

   出力例

   var.create_vpc
     If you would like to create a new VPC, set this value to 'true'. If you do not want to create a new VPC, set this value to 'false'.
   
     Enter a value:
   
   var.private_cluster
     If you want to create a private cluster, set this value to 'true'. If you want a publicly available cluster, set this value to 'false'.
   
     Enter a value:

4. Terraform インターフェイスに作成または変更するリソースがリストされ、確認を求めるプロンプトが表示されたら、続行するには yes を、キャンセルするには no を入力します。

   出力例

   Plan: 74 to add, 0 to change, 0 to destroy.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes

   yes と入力すると、Terraform プランが開始され、AWS アカウントロール、Operator ロール、ROSA Classic クラスターが作成されます。

検証

1. 次のコマンドを実行して、クラスターが作成されたことを確認します。

   $ rosa list clusters

   クラスターの ID、名前、ステータスを示す出力例

   ID                                NAME          STATE  TOPOLOGY
   27c3snjsupa9obua74ba8se5kcj11269  rosa-tf-demo  ready  Classic (STS)

2. 次のコマンドを実行して、アカウントロールが作成されたことを確認します。

   $ rosa list account-roles

   出力例

   I: Fetching account roles
   ROLE NAME                                   ROLE TYPE      ROLE ARN                                                           OPENSHIFT VERSION  AWS Managed
   ROSA-demo-ControlPlane-Role                 Control plane  arn:aws:iam::<ID>:role/ROSA-demo-ControlPlane-Role                 4.14               No
   ROSA-demo-Installer-Role                    Installer      arn:aws:iam::<ID>:role/ROSA-demo-Installer-Role                    4.14               No
   ROSA-demo-Support-Role                      Support        arn:aws:iam::<ID>:role/ROSA-demo-Support-Role                      4.14               No
   ROSA-demo-Worker-Role                       Worker         arn:aws:iam::<ID>:role/ROSA-demo-Worker-Role                       4.14               No

3. 次のコマンドを実行して、Operator ロールが作成されたことを確認します。

   $ rosa list operator-roles

   Terraform で作成された Operator ロールを示す出力例

   I: Fetching operator roles
   ROLE PREFIX    AMOUNT IN BUNDLE
   rosa-demo      6

手順

1. terraform apply コマンドを実行してクラスターを作成したディレクトリーで、次のコマンドを実行してクラスターを削除します。

   $ terraform destroy

   Terraform インターフェイスでは、2 つの変数の入力を求められます。これらは、クラスターの作成時に指定した回答と一致する必要があります。

   var.create_vpc
     If you would like to create a new VPC, set this value to 'true.' If you do not want to create a new VPC, set this value to 'false.'
   
     Enter a value:
   
   var.private_cluster
     If you want to create a private cluster, set this value to 'true.' If you want a publicly available cluster, set this value to 'false.'
   
     Enter a value:

2. yes と入力して、ロールとクラスターの削除を開始します。

   出力例

   Plan: 0 to add, 0 to change, 74 to destroy.
   
   Do you really want to destroy all resources?
     Terraform will destroy all your managed infrastructure, as shown above.
     There is no undo. Only 'yes' will be accepted to confirm.
   
     Enter a value: yes

検証

1. 次のコマンドを実行して、クラスターが破棄されたことを確認します。

   $ rosa list clusters

   クラスターがないことを示す出力例

   I: No clusters available

2. 次のコマンドを実行して、アカウントロールが破棄されたことを確認します。

   $ rosa list account-roles

   Terraform で作成されたアカウントロールがないことを示す出力例

   I: Fetching account roles
   I: No account roles available

3. 次のコマンドを実行して、Operator ロールが破棄されたことを確認します。

   $ rosa list operator-roles

   Terraform で作成された Operator ロールがないことを示す出力例

   I: Fetching operator roles
   I: No operator roles available