3.3. Advanced Concepts and Theory

Procedure 3.7. Task

1. In this example we will use a bus pass issuing system. See the code snippet below:

   rule "Issue Child Bus Pass" when
     $p : Person( age < 16 )
   then
     insert(new ChildBusPass( $p ) );
   end
    
   rule "Issue Adult Bus Pass" when
     $p : Person( age >= 16 )
   then
     insert(new AdultBusPass( $p ) );
   end

   Copy to Clipboard Toggle word wrap
2. Insert the insertLogical property to provide inference:

   rule "Infer Child" when
       $p : Person( age < 16 )
   then
       insertLogical( new IsChild( $p ) )
   end
   rule "Infer Adult" when
       $p : Person( age >= 16 )
   then
       insertLogical( new IsAdult( $p ) )
   end

   Copy to Clipboard Toggle word wrap
3. Re-enter the code to issue the passes. These two configurations can also be logically inserted, as the TMS supports chaining of logical insertions for a cascading set of retracts:

   rule "Issue Child Bus Pass" when
     $p : Person( )
          IsChild( person == $p )
   then
       insertLogical(new ChildBusPass( $p ) );
   end
    
   rule "Issue Adult Bus Pass" when
     $p : Person( age >= 16 )
          IsAdult( person =$p )
   then
       insertLogical(new AdultBusPass( $p ) );
   end

   Copy to Clipboard Toggle word wrap
   Now when the person changes from being 15 to 16, both the IsChild fact and the person's ChildBusPass fact are automatically retracted.
4. Optionally, insert the not conditional element to handle notifications. (In this example, a request for the returning of the pass.) When the TMS automatically retracts the ChildBusPass object, this rule triggers and sends a request to the person:

   rule "Return ChildBusPass Request "when
     $p : Person( )
          not( ChildBusPass( person == $p ) )
   then
       requestChildBusPass( $p );
   end

   Copy to Clipboard Toggle word wrap