1.4. 从 Terraform 集成

流程

1. 登录到 Ansible Automation Platform 用户界面。
2. 导航到 Automation Decisions Event Streams。
3. 点 Create event stream。

4. 在 Create event stream 页面中，编辑字段：

   • 名称 ： 您的事件流的描述性、唯一名称（如 Terraform provider_Events）。
   • Organization ： 选择此事件流将属于的机构（通常为 Default 或 your specific organization）。
   • event stream type ： 选择与您要接收事件匹配的类型。此集成支持 基本事件流 （用户名/密码）。
   • 凭证 ： 选择一个您预先创建用于使用此事件流进行身份验证的凭证。
   • headers ：（可选）输入您要包含在转发到规则规则的事件有效负载中的以逗号分隔的 HTTP 标头键。保留此为空以包括所有标头。
   • 将事件转发到规则手册激活 ： 此选项通常默认启用。禁用它可用于测试和诊断您的连接和传入的数据，而不会意外地触发任何自动化。

5. 点 Create event stream。然后导航到 Automation Decisions Event Streams，以验证事件流是否已创建并查看目前收到的事件数量。

   您还可以点击特定流来查看其详细配置，包括机构、事件流类型、关联的凭证和事件转发设置。

6. 设置 规则手册激活。确保：

   1. 将事件流添加到规则手册中。
   2. （推荐）选择 启用 Rulebook 激活？ 选项，以在创建后自动启动激活。
   3. 激活规则手册。
7. 选择 Automation Decisions Rulebook Activations，以验证规则手册是否活跃并检查其状态。

流程

1. 添加一个 lifecycle 块，将 Event-Driven Ansible 事件流调用到您的 storageclasstf 文件。after_create 操作将触发 action.aap_eda_eventstream_post.create。

   示例

   以下示例显示了添加到 AWS EC2 服务器的置备 生命周期 块。调配新的服务器后，操作将运行。

   terraform {
     required_providers {
       aws = {
         source  = "hashicorp/aws"
         version = "~> 6.0"
       }
   
       aap = {
         source  = "ansible/aap"
         version = "~> 1.4.0"
       }
     }
   }
   
   provider "aap" {
     # Configure authentication as needed.
   }
   
   provider "aws" {
     region = "us-west-1"
     # Configure authentication as needed.
   }
   
   variable "public_key_path" {
     type        = string
     description = "Local path to a public key file to inject into the VM. Your AAP Job Template must have the matching private key configured as a machine credential."
   }
   
   variable "event_stream_username" {
     type = string
   }
   
   variable "event_stream_password" {
     type = string
   }
   
   resource "aws_key_pair" "key_pair" {
     key_name   = "aap-terraform-actions-demo-key"
     public_key = file(var.public_key_path)
   }
   
   data "aws_ami" "rhel_ami" {
     most_recent = true
   
     filter {
       name   = "name"
       values = ["RHEL-9*"]
     }
   
     filter {
       name   = "virtualization-type"
       values = ["hvm"]
     }
   
     owners = ["309956199498"] # Red Hat
   }
   
   resource "aws_instance" "instance" {
     ami                         = data.aws_ami.rhel_ami.id
     instance_type               = "t2.micro"
     associate_public_ip_address = true
     key_name                    = aws_key_pair.key_pair.key_name
   }
   
   # Look up an inventory
   
   data "aap_inventory" "inventory" {
     name              = "EDA Actions Demo Inventory"
     organization_name = "Default"
   }
   
   #
   # EDA Event launch action example
   #
   
   resource "aap_host" "host" {
     inventory_id = data.aap_inventory.inventory.id
     name         = resource.aws_instance.instance.public_ip
     # Configure an EDA eventstream POST after the host is created in inventory
     lifecycle {
       action_trigger {
         events  = [after_create]
         actions = [action.aap_eda_eventstream_post.event_post]
       }
     }
   }
   
   data "aap_eda_eventstream" "eventstream" {
     name = "TF Actions Event Stream"
   }
   
   action "aap_eda_eventstream_post" "event_post" {
     config {
       limit             = "all"
       template_type     = "job"
       job_template_name = "Demo Job Template"
       organization_name = "Default"
       event_stream_config = {
         username = var.event_stream_username
         password = var.event_stream_password
         url      = data.aap_eda_eventstream.eventstream.url
       }
     }
   }

2. （必需）配置以下参数：

   • event-Driven Ansible 事件流的event_stream_config: (Attributes) Details。您必须包括：

     • 用户名 ：( 字符串)在执行 POST 到事件流 URL 时使用的用户名
     • Password : （字符串）在执行 POST 到事件流 URL 时使用的密码
     • URL : （字符串）用于接收事件 POST 的 URL
   • 限制 ： （字符串）Ansible Automation Platform 对作业执行的限制
   • organization_name ：( 字符串)机构名称
   • template_type: （字符串）模板类型： job 或 workflow_job
3. （可选）您可以将所有者设置为 Red Hat RHEL 镜像 ID，以便每次作业运行时都会使用最新的镜像。
4. （可选）根据需要设置 附加参数。

5. 配置与事件有效负载规格和目标规则手册映射的操作集成。

   示例：

流程

1. 运行 terraform init 以初始化您的工作目录。

2. 使用 terraform 计划 提交来创建计划。以下示例将计划保存到名为 tfplan.out 的文件，但您可以为计划指定任何名称。保存计划是自动化的最佳做法，因为保存的计划严格强制执行。

   terraform plan -out=tfplan.out

3. 检查计划输出。

4. 应用已保存的计划。

   terraform apply tfplan.out

   这会创建事件并将其发送到指定的事件流。当创建每个资源时，会调用 TF 操作，并按顺序执行对应的 Ansible Automation Platform playbook。

验证

1. 验证在 Terraform 用户界面中是否更新了运行。深入到资源上，以查看调用该操作和执行后事件。

2. 在 Ansible Automation Platform 用户界面中，验证事件是否被(EDAName})成功接收，并触发适当的规则手册激活：

   1. 检查 Event Streams 仪表板，以查看收到 TF Actions 事件。
   2. 检查 Jobs 仪表板，以查看按顺序运行的作业以及 Success 状态。
   3. 检查 Inventory 仪表板，以查看更新。例如，如果您创建了新的服务器，请检查 Terraform 置备清单的 Hosts 选项卡。